Uitwisselprofiel Zorgkantoren Inkoopondersteuning en beleidsontwikkeling

Over Uitwisselprofiel Zorgkantoren Inkoopondersteuning en beleidsontwikkeling

Publicatiedatum:
09-03-2026
Inwerkingtreding:
09-03-2026
Bekijk bron...

14.3 Wat is het aantal cliënten met een Wlz-indicatie per zorgprofiel VV en leveringsvorm?

Concepten

Relaties

Eigenschappen

Instanties

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 14.3
2# Parameters: ?peildatum, ?zorgkantoor
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-g:   <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg:<http://purl.org/ozo/onz-zorg#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX rdf:     <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
9PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd:     <http://www.w3.org/2001/XMLSchema#>
11
12SELECT
13  (?zorgprofiel AS ?Zorgprofiel)
14  (SUM(?max_vmb) AS ?Verblijf_met_behandeling)
15  (SUM(?max_vzb) AS ?Verblijf_zonder_behandeling)
16  (SUM(?max_vpt) AS ?VPT)
17  (SUM(?max_mpt) AS ?MPT)
18  (SUM(?max_pgb) AS ?PGB)
19  (SUM(IF((?max_vmb + ?max_vzb + ?max_vpt + ?max_mpt + ?max_pgb) > 0, 1, 0)) AS ?Totaal)
20WHERE {
21  {
22    SELECT
23      ?client
24      ?zorgprofiel
25      (MAX(?vmb) AS ?max_vmb)
26      (MAX(?vzb) AS ?max_vzb)
27      (MAX(?vpt) AS ?max_vpt)
28      (MAX(?mpt) AS ?max_mpt)
29      (MAX(?pgb) AS ?max_pgb)
30    WHERE {
31      #BIND ("2023-01-01"^^xsd:date AS ?peildatum)
32      VALUES ?zorgprofiel { onz-zorg:4VV onz-zorg:5VV onz-zorg:6VV onz-zorg:7VV onz-zorg:8VV onz-zorg:9BVV onz-zorg:10VV }
33
34      # Zorgprocessen binnen peildatum
35      ?zorgproces a onz-zorg:NursingProcess ;
36                  onz-g:definedBy ?indicatie ;
37                  onz-g:hasPerdurantLocation ?locatie ;
38                  onz-g:startDatum ?start_zorgproces .
39      OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces }
40      FILTER (?start_zorgproces <= ?peildatum && ((?eind_zorgproces >= ?peildatum) || !BOUND(?eind_zorgproces)))
41
42      ?locatie a onz-g:StationaryArtifact ; onz-g:partOf* ?vestiging_uri .
43      ?vestiging_uri a onz-org:Vestiging ;
44         onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
45      BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
46      ?pc_gebied onz-g:identifiedBy ?postcode ; onz-g:partOf+ ?zk_regio .
47      ?zk_regio a onz-org:ZorgkantoorRegio .
48      ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
49
50      # Indicatie + cliënt
51      ?indicatie onz-g:hasPart ?zorgprofiel ;
52                 onz-g:hasPart ?lv ;
53                 onz-g:isAbout ?client ;
54                 a onz-zorg:WlzIndicatie .
55
56      # Indicatie filter peildatum 
57      ?indicatie onz-g:startDatum ?ind_start .
58      OPTIONAL { ?indicatie onz-g:eindDatum ?ind_eind }
59      FILTER (?ind_start <= ?peildatum && ((?ind_eind >= ?peildatum) || (!BOUND(?ind_eind))))
60
61      ## Van de indicatiebesluiten3 met leveringsvorm5 verblijf8 bepaal of het met of zonder behandeling7 is.
62      OPTIONAL { ?indicatie onz-zorg:heeftIndicatieBehandeling ?behandeling }
63      BIND(IF(BOUND(?behandeling), ?behandeling, "false"^^xsd:boolean) AS ?incl_behandeling)
64
65      ?client a onz-g:Human .
66      ?lv a onz-zorg:Leveringsvorm .
67
68      # Vlaggen per indicatie
69      BIND(IF(?lv = onz-zorg:instelling && ?incl_behandeling,      1, 0) AS ?vmb)
70      BIND(IF(?lv = onz-zorg:instelling && !?incl_behandeling,     1, 0) AS ?vzb)
71      BIND(IF(?lv = onz-zorg:vpt,                                  1, 0) AS ?vpt)
72      BIND(IF(?lv = onz-zorg:mpt,                                  1, 0) AS ?mpt)
73      BIND(IF(?lv = onz-zorg:pgb,                                  1, 0) AS ?pgb)
74    }
75    GROUP BY ?client ?zorgprofiel
76  }
77}
78GROUP BY ?zorgprofiel
79
Terug naar: 14.2 Wat is het aantal cliënten per leveringsvorm met zorgprofiel VV?